**突破趋势线指标（源码 主图 通达信 贴图）**

<http://www.55188.com/thread-8052376-1-1.html>

**主图指标源码奉上~看看有没有高人能够做出选股公式出来~~  
要求就是当日股价突破上方红色趋势线发出信号~~~**

源码：  
  
{连结MACD相邻红绿柱区间内高低点画趋势线 通达信}  
  
DIFF:=EMA(CLOSE,12)-EMA(CLOSE,26);  
DEA:=EMA(DIFF,9);  
  
N1:=BARSLAST(CROSS(DIFF,DEA))+1;{最近一次满足条件DIFF上穿DEA的K线到当前的距离}  
N2:=BARSLAST(CROSS(DEA,DIFF))+1;{最近一次满足条件DIFF下穿DEA的K线到当前的距离}  
  
  
{当前是DIFF>DEA的状态，连结最近两个DIFF>DEA区间（不包含当前区间）内最高点的趋势线}  
A1:=BACKSET(ISLASTBAR && N1<N2,REF(REF(HHVBARS(H,N1)+1,N2),N2)+REF(N2,N2)+N2);  
B1:=BACKSET(ISLASTBAR && N1<N2,REF(HHVBARS(H,N1),N2)+N2+1);  
DRAWLINE(CROSS(A1,0.5),H,CROSS(B1,0.5),H,1),COLORRED;  
  
{当前是DIFF>DEA的状态，连结最近两个DIFF<DEA区间内最低点的趋势线}  
A2:=BACKSET(ISLASTBAR && N1<N2,REF(REF(LLVBARS(L,N2)+1,N1),N2)+REF(N1,N2)+N2);  
B2:=BACKSET(ISLASTBAR && N1<N2,REF(LLVBARS(L,N2)+1,N1)+N1);  
DRAWLINE(CROSS(A2,0.5),L,CROSS(B2,0.5),L,1),COLORGREEN;  
  
{当前是DIFF<DEA的状态，连结最近两个DIFF<DEA区间（不包含当前区间）内最低点的趋势线}  
A3:=BACKSET(ISLASTBAR && N1>N2,REF(REF(LLVBARS(L,N2)+1,N1),N1)+REF(N1,N1)+N1);  
B3:=BACKSET(ISLASTBAR && N1>N2,REF(LLVBARS(L,N2),N1)+N1+1);  
DRAWLINE(CROSS(A3,0.5),L,CROSS(B3,0.5),L,1),COLORGREEN;  
  
{当前是DIFF<DEA的状态，连结最近两个DIFF>DEA区间内最高点的趋势线}  
A4:=BACKSET(ISLASTBAR && N1>N2,REF(REF(HHVBARS(H,N1)+1,N2),N1)+REF(N2,N1)+N1);  
B4:=BACKSET(ISLASTBAR && N1>N2,REF(HHVBARS(H,N1)+1,N2)+N2);  
DRAWLINE(CROSS(A4,0.5),H,CROSS(B4,0.5),H,1),COLORRED;

选股公式如下,能达到基本要求,除去未交易的74支,排除10亿以上的剩下45支.不同的形态,需要综合分析.仁者见仁,不喜勿喷,纯粹交流.  
DIFF:=EMA(CLOSE,12)-EMA(CLOSE,26);DEA:=EMA(DIFF,9);  
N1:=BARSLAST(CROSS(DIFF,DEA))+1;N2:=BARSLAST(CROSS(DEA,DIFF))+1;  
  
A1:=BACKSET(ISLASTBAR && N1<N2,REF(REF(HHVBARS(H,N1)+1,N2),N2)+REF(N2,N2)+N2);  
B1:=BACKSET(ISLASTBAR && N1<N2,REF(HHVBARS(H,N1),N2)+N2+1);  
KKA:=DRAWLINE(CROSS(A1,0.5),H,CROSS(B1,0.5),H,1);  
  
A4:=BACKSET(ISLASTBAR && N1>N2,REF(REF(HHVBARS(H,N1)+1,N2),N1)+REF(N2,N1)+N1);  
B4:=BACKSET(ISLASTBAR && N1>N2,REF(HHVBARS(H,N1)+1,N2)+N2);  
KKB:=DRAWLINE(CROSS(A4,0.5),H,CROSS(B4,0.5),H,1);  
  
AAA:=C>KKA;BBB:=C>KKB;  
(CROSS(AAA>REF(AAA,1),0.5) OR CROSS(BBB>REF(BBB,1),0.5)) AND DYNAINFO(17)>0;

建议再结合 MA2 均线分析,均线多头向上,一般都会有一波上涨 例如 600306 300295.该指标用于趋势判断还是有帮助的.忌用一个指标打天下,成功率低.

指标总体来看,成功率还行,必需要结合均线来做决策,强者恒强,开盘前关注竞价图趋势上行还是下行,实盘当中找相应的低点介入,还是有赚.

[@灌肠儿](http://www.55188.com/space-uid-1420894.html) 多亏你的名字还记得,短信删掉了,找不到回复 自行再加入条件限制出票数量  
DIFF:=EMA(CLOSE,5)-EMA(CLOSE,13);DEA:=EMA(DIFF,9);A1:=BARSLAST(REF(CROSS(DIFF,DEA),1));  
底背离:=REF(CLOSE,A1+1)>CLOSE AND DIFF>REF(DIFF,A1+1) AND CROSS(DIFF,DEA);  
  
OBV0:=SUM(IF(CLOSE>REF(CLOSE,1),VOL,IF(CLOSE<REF(CLOSE,1),-VOL,0)),0);  
OBV:=OBV0/100000;MA30:=MA(OBV,21);OBV1:=OBV-MA30;中均:=EMA(OBV1,20);短均:=EMA(OBV1,5);  
红柱:=REF(中均,1)>REF(短均,1) AND 短均>=中均 AND OBV1>REF(OBV1,1);  
  
红柱;  
  
{底背离;} {针对底背离选股}  
  
{红柱 OR 底背离;}{一起选出};